L’explorateur de fichiers Windows est facile à naviguer et est livré avec de nombreuses fonctionnalités d’accessibilité intéressantes, dont les paramètres d’affichage des dossiers. Vous pouvez personnaliser les dossiers pour représenter le type de fichiers qu’ils stockent.

Par exemple, si vous avez un dossier dans lequel vous n’avez enregistré que des vidéos, vous pouvez configurer le dossier pour qu’il affiche les vignettes des vidéos au lieu d’une liste ou des détails du fichier. Vous pouvez également personnaliser chaque dossier pour afficher des icônes moyennes, grandes ou extra-larges.

Après avoir effectué ces modifications, vous souhaiterez peut-être les sauvegarder afin de restaurer les paramètres d’affichage des dossiers s’ils sont réinitialisés. Ce guide vous montre comment sauvegarder et restaurer vos paramètres d’affichage de dossier à l’aide d’un fichier batch.

Sauvegarder et restaurer les paramètres d’affichage des dossiers dans Windows 11/10

Suivez les étapes ci-dessous pour sauvegarder et restaurer vos paramètres d’affichage des dossiers dans Windows 11/10.

1. Créez le fichier batch de sauvegarde et de restauration.
2. Débloquez le fichier .bat s’il est bloqué par Windows.
3. Exécutez le fichier .bat pour sauvegarder et restaurer les paramètres d’affichage de vos dossiers.

Sans plus tarder, nous allons maintenant passer directement aux étapes détaillées impliquées dans la réalisation des opérations ci-dessus.

1]Créez le fichier de commandes de sauvegarde et de restauration

Clique sur le Démarrer bouton et recherchez Bloc-notes. Sélectionnez l’application Bloc-notes dans les résultats de la recherche pour la lancer.

Saisissez le texte suivant dans le nouveau fichier Bloc-notes :

@ECHO OFF

title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice

:verify1
IF EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice

:backup
mkdir "%userprofile%\Desktop\Folder View Settings Backup"
REG EXPORT HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice

:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

Vous pouvez copier et coller le texte ci-dessus dans la note. Ensuite, appuyez sur CTRL + S et enregistrez le fichier sur votre bureau avec le .chauve souris extension. Faites cela en ajoutant .chauve souris à la fin du nom de fichier avant d’appuyer sur le Sauver bouton.

Les fichiers enregistrés dans l’extension .bat sont des fichiers batch et lorsqu’ils sont correctement exécutés, ils vous permettent d’exécuter des commandes sur votre système Windows. Apprenez-en plus sur les fichiers batch et explorez ces astuces intéressantes.

2]Débloquer le fichier .bat

Après avoir enregistré avec succès le fichier nouvellement créé en tant que .chauve souris fichier, Windows peut le bloquer. Pour exécuter ce fichier, vous devez d’abord le débloquer. Pour ce faire, faites un clic droit sur le fichier et sélectionnez Propriétés depuis le menu contextuel.

Passez à la Général de la fenêtre Propriétés et recherchez l’onglet Débloquer case à cocher vers le bas de la fenêtre. Cochez cette case et appuyez sur le D’ACCORD bouton pour débloquer le fichier batch.

REMARQUE: Si la Débloquer case à cocher est manquante dans votre configuration, cela signifie que Windows n’a pas bloqué le fichier et vous pouvez passer à l’étape suivante.

3]Exécutez le fichier .bat

Après avoir débloqué le fichier .bat, vous êtes prêt à partir. Vous pouvez exécuter le fichier .bat en double-cliquant dessus. L’exécution du fichier de commandes ouvre une fenêtre d’invite de commande qui affiche les options suivantes :

• Sauvegardez vos paramètres d’affichage de dossier.
• Restaurer les paramètres d’affichage des dossiers à partir de la sauvegarde.
• Annuler.

Pour sauvegarder vos paramètres d’affichage de dossier, appuyez sur 1 et appuyez sur la touche ENTRÉE. Si vous souhaitez restaurer les paramètres d’affichage de votre dossier, appuyez sur 2 et appuyez sur ENTREE.

Sinon, appuyez sur 3 pour annuler l’opération.

J’espère que cela t’aides.